Någon som vet om det går/hur man gör för att fånga vilken användare som är inne på asp-sidan ? Sidorna finns på ett intranät och jag undrar om det ev går att ta den från AD't ? Jag vill nämligen unvika att någon form av manuell inloggning. Miljön är W2000-server och IIS 5.0 (ej asp.net).

Mvh Stefan

Jag sitter också på ett intranät och
jag har löst det så här.
Det kanske finns bättre sätt

På en sida som includeras på de sidor där
validering behövs hämtar jag först inloggad med

<code>
CurrUser = LCase(Request.ServerVariables("LOGON_USER"))
</code>

För enstaka medlemmar sätter jag ihop en Array så här

<code>
' ### Deltagare utan grupptillhörighet ####
AllAdmin = "DOMÄNNAMN\INLOGGNINGSID" ' En deltagare
AllAdmin = AllAdmin & "," & "DOMÄNNAMN\INLOGGNINGSID" ' nästa deltagare osv
</code>

Sen har jag gjort en funktion som returnerar sant om inloggad finns
i arrayen

<code>
' ## Function för kontroll av enstaka deltagare ##
Function CHECKUSER(sUser, aNewArrray)
Dim i
CHECKUSER = False
NewArray = Split(aNewArrray, ",", -1, vbTextCompare)
For i = 0 To UBound(NewArray)
If LCase(NewArray(i)) = sUser Then
CHECKUSER = True
Exit For
End If
Next
End Function
</code>

Funktionen anropas så här
<code>
AdminOK = CHECKUSER(CurrUser, AllAdmin)
</code>


Sen har jag en funktion för deltagare som ingår i en grupp
som jag anropar ifall jag inte fått träff i den första funktionen

<code>

If Not AdminOK Then
AdminOK = CHECKUSER2(CurrUser)
End If


' ## Function för kontroll av deltagare ingående i behörighetsgrupp ##
Function CHECKUSER2(sUser)
CHECKUSER2 = False
Set objUser = GetObject("WinNT://" & Replace(sUser,"\","/"))
For Each objGroup In objUser.Groups
Select Case objGroup.Name
Case "NAMN PÅ GRUPP"
CHECKUSER2 = True
Exit For
End Select
Next
End Function
</code>

Nu kan jag använda variabeln AdminOK
för att ex dölja en länk för alla utom de som är behöriga
eller redirecta behöriga till en sida och obehöriga till en annan
ex
<code>
<%
If AdminOK Then
%>
länk till sida....
<%
End If
%>
</code>

Som sagt det kanske finns bättre lösningar
men detta fungerar för mig

Fungerar klockrent ! Ett stort tack Thommy !