När jag lägger till nyheter visas datumet varje gång, tillexempel

2004-05-20: Nyhet 1
2004-05-20: Nyhet 2
2004-05-20: Nyhet 3
2004-05-19: Nyhet 4
2004-05-19: Nyhet 5

Kan man göra så att varje datum bara visas en gång? Så det blir typ

2004-05-20: Nyhet 1
Nyhet 2
Nyhet 3
2004-05-19: Nyhet 4
Nyhet 5

eller nåt liknande?? Nån som vet?

Alltså nåt i stil med

If Datum = samma
then
skriv inte
else
skriv ut datumet

Jaja, ni fattar säkert. Är ganska ny på det här så ta det lungt!

Löste det själv.

<%if dtmDate <> recset("datum") then Response.write(recset("datum"))
dtmDate = recset("datum")%>

Jag väljer att utveckla Björn Bejegård exempel för at tydligöra:
<code>
<%
'**
'* Deklarerar variabler
'**
Dim rs
Dim con

Dim fldDate
Dim fldText

Dim strSQL
Dim LastDate

'**
'* Öppnar anslutning till databas
'**
Set con = Server.CreateObject("ADODB.Connection")
con.Open "<<<Din anslutnings sträng>>>"

'**
'* Öppnar anslutning till recordset (recordset är ett objet vilket läser data från en tabell/frågeresultat)
'**
strSQL = "SELECT *" & vbCrLf & _
"FROM DinTabell" & vbCrLf & _
"ORDER BY DatumFält DESC"

Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open strSQL, con

'**
'* Hämtar referens till fält för snabbare adressering av fält från recordset.
'* Ger bättre prestanda!
'**
Set fldDate = rs("DatumFält")
Set fldText = rs("TextFält")

'**
'* Enumererar recordset
'**
Response.Write "<TABLE>"
Do Until rs.EOF
'**
'* Kontrollerar om datum skall skrivas ut
'**
Response.Write "<TR><TD>"
If LastDate <> fldDate.Value Then
'**
'* Skriver ut datum
'**
Response.Write fldDate.Value

LastDate = fldDate.Value
End If
Response.Write "</TD><TD>"
'**
'* Skriver ut text
'**
Response.Write Server.HTMLEncode(fldText.Value)
Response.Write "</TD></TR>"
rs.MoveNext
Loop
Response.Write "</TABLE>"

'**
'* Frigör fältvariabler
'**
Set fldDate = Nothing
Set fldText = Nothing

'**
'* Stänger och frigör recordset
'**
rs.Close
Set rs = Nothing

'**
'* Stänger och frigör databas anslutning
'**
con.Close
Set con = Nothing
%>
</code>

P.S.
Har lagt ner lite extra tid på just detta exemplet för att visa hur "fint" ett bra exempel ser ut och uppskattas. Uppmanar er alla som har tid att lägga ner lite av den på inlägen ni skriver. Detta skulle höja kvalitén på Pellesoft ytterligare. Det är väl inte fel. ;o)
D.S.

Okej förlåt.. skall tänka på det till nästa gång =)