Har kört fast med ett litet formulärscript på min adminsida.

På sidan kan jag se alla länkar jag har, och jag har även en radio där jag kan välja om länkarna ska visas eller ej. Nu försöker jag lägga till en checkbox där jag markerar om länken är fel, men när jag skall ändra det från adminsidan blir det helt galet.

<input type="radio" name="<%=RecSet("id")%>" value="ja" <%If RecSet("visa") = True Then Response.Write "checked"%>><input type="radio" name="<%=RecSet("id")%>" value="nej" <%If RecSet("visa") = False Then Response.Write "checked"%>>

<input type="checkbox" name="<%=RecSet("id")%>" value="fel" <%If RecSet("fel") = True Then Response.Write "checked"%>


Och lite längre ner där jag ändrar:


<%
For each id In Request.Form

strShow = "False"
strError = "False"

For each value in id
If value = "ja" Then strShow = "True"
If value = "fel" Then strError = "True"
Next

Conn.Execute "Update linkz Set visa=" & strShow & ", fel=" & strError & " Where id=" & id,,128

Next
%>


Får följande fel:

"Object not a collection"

på raden

For each value in id
If value = "ja" Then strShow = "True"
If value = "fel" Then strError = "True"


Någon hjälte som kan hjälpa mig??

Jag TROR det skall vara:
<code>
<%
For each id In Request.Form

strShow = "False"
strError = "False"

For each value in Request.Form(id)
If value = "ja" Then strShow = "True"
If value = "fel" Then strError = "True"
Next

Conn.Execute "Update linkz Set visa=" & strShow & ", fel=" & strError & " Where id=" & id,,128

Next
%>
</code>

Annars skulle jag gjort så här:

<code>

Do Until RecSet.EOF
Index = Index + 1
Response.Write "<input type=""hidden"" name=""post(" & Index & ").id"" value=""" & RecSet("id") & """>"
If RecSet("visa") = True Then
Response.Write "<input type=""radio"" name=""post(" & Index & ").visa"" value=""ja"" checked>"
Response.Write "<input type=""radio"" name=""post(" & Index & ").visa"" value=""nej"">"
Else
Response.Write "<input type=""radio"" name=""post(" & Index & ").visa"" value=""ja"">"
Response.Write "<input type=""radio"" name=""post(" & Index & ").visa"" value=""nej"" checked>"
End If

If RecSet("fel") = True Then
Response.Write "<input type=""checkbox"" name=""post(" & Index & ").fel"" value=""fel"" checked>"
Else
Response.Write "<input type=""checkbox"" name=""post(" & Index & ").fel"" value=""fel"">"
End If
RecSet.MoveNext
Loop
Response.Write "<input type=""hidden"" name=""post.count"" value=""" & Index & """>"
</code>

För att sedan kontrollera resultatet genom:

<code>

Dim id
Dim fel
Dim visa
Dim Count

Count = CLng(Request.Form("post.count"))

For Index = 1 To Count
id = Request.Form("post(" & Index & ").id")
fel = Request.Form("post(" & Index & ").fel")
visa = Request.Form("post(" & Index & ").visa")
Next
</code>

Det första du skrev fungerade alldeles utmärkt. Tusen tack!