Tjena!

Någon som vet hur man gör om man först exporterar till en semikolon avgränsad fil och sedan via script trycker in detta i en databas?

Mvh Andreas

Öppna filen mha FSO och läs in raderna(=posterna). Splitta dom vid semikolon och tryck in värdena i databasen.
Ungefär så här:
<code>
<%
Const filnamn = "/filnamn.txt" ' filnamn

Dim FSO, path
set FSO = server.createObject("Scripting.FileSystemObject")
path = Server.MapPath(filnamn)

if FSO.FileExists(path) Then
Dim file, TS, post, field ' , i
Set file = FSO.GetFile(path)
Set TS= file.OpenAsTextStream(1, -2)
Do While Not TS.AtEndOfStream
post = TS.readline
field = Split(post,";") ' Splitta posten i fält

' Tryck in data i databasen...

' Bygg upp SQL strängen, t ex så här:
' sqlstr = "INSERT INTO tabell VALUES ("
' For i = 0 to uBound(field)
' sqlstr = sqlstr & "'" & field(i) & "',")
' Next
' sqlstr = Left(sqlstr,len(sqlstr)-1) & ")" ' Byt sista komma mot parentes

Loop
Set TS = nothing
Else
' Error: Filen finns inte
End If
Set FSO = nothing
%>
</code>

Du har ju en exportfunktion i Outlook (Arkiv/Imprtera och Exportera...) Där väljar du Exportera till fil, och i nästa som semikolonavgränsad fil
Eller menar du att du redan i asp skall exortera ut innehållet i Outlook till fil?

Nä det jag vill göra är att läsa in en redan exporterad semikolonavgränsad fil via asp till en databas.

Tex.
Benny exporterar sina kontakter till en semikolonavgränsad fil.
Han laddar sedan in/upp den på en webserver.
I samma veva som den laddas upp skall infon läsas ur filen och tryckas ner i en databas.
Benny har sedan sina kontakter på webbsidan

Filen som kommer från outlook blir en xxx.CVS och det är väl en excel-fil?

:)

Mvh Andreas

Min kod ovan borde funka. Om du är osäker på hur man laddar upp filer så sök på "tips och tricks"

Det blir en csv(<b>c</b>omma <b>s</b>eparated <b>v</b>alues)-fil... vilket egentligen är en vanlig textfil...

Ladda upp är inga problem.

Du skulle möjligtvis inte vilja visa hur man gör för att skriva ut infon direkt på sidan istället för att trycka ner det i en databas? Fick inte till det själv :)

ok... jag har följande filer i en mapp på webbservern:

backup.csv
**************
<code>
Pelle;Johansson;pellesoft.se;Älvsjö;mail@pellesoft.se
Yandar;Mabuti;mydomain.com;Kuala Lumpur;info@mydomain.com
Kalle;Anka;ankeborg.se;Ankeborg;kvack@ankeborg.se
</code>

printTable.asp
**************
<code>
<%

' vbTab och vbCrLf används endast nedan för att formatera källkoden

Const filnamn = "backup.csv"
Dim FSO, path
set FSO = server.createObject("Scripting.FileSystemObject")
path = Server.MapPath(filnamn)
if FSO.FileExists(path) Then
Dim file, TS, post, field, i
Set file = FSO.GetFile(path)
Set TS= file.OpenAsTextStream(1, -2)
Response.Write("<table border=""1"">" & vbCrLf) ' Skriv ut i en tjusig tabell... ;)
Do While Not TS.AtEndOfStream
post = TS.readline
field = Split(post,";")
Response.Write(vbTab & "<tr>" & vbCrLf) ' Ny tabellrad
For i = 0 to uBound(field)
Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(i))
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn
Next
Response.Write(vbTab & "</tr>" & vbCrLf) ' Avsluta tabellrad
Loop
Response.Write("</table>") ' Avsluta tabell
Set TS = nothing
Else
Response.Write("Error: Filen finns inte!")
End If
Set FSO = nothing
%>
</code>
Obs! FSO måste tillåtas på servern och scriptblocking i t ex NAV kan ställa till problem.

Det där gick ju som smort :)

En fråga till:
Vet du hur man skriver om man endast vill hämta vissa av värdena i cvs filen? Tex. Förnamn, efternamn & E-mail?

Mvh Andreas

Enklast är väl att skippa loopen:

For i = 0 to uBound(field)
Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(i))
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn
Next

Och istället:

Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(0)) ' Kolumen noll, förnamn
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn

Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(1)) ' Kolumn 1 , efternamn
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn

Så du väljer då ut de kolumner du vill ha presenterade.

Tja!

Är det såhär du menar?

<code>
<%

Const filnamn = "backup.csv"
Dim FSO, path
set FSO = server.createObject("Scripting.FileSystemObject")
path = Server.MapPath(filnamn)
if FSO.FileExists(path) Then
Dim file, TS, post, field, i
Set file = FSO.GetFile(path)
Set TS= file.OpenAsTextStream(1, -2)
Response.Write("<table border=""1"">" & vbCrLf) ' Skriv ut i en tjusig tabell... ;)
Do While Not TS.AtEndOfStream
post = TS.readline
field = Split(post,";")
Response.Write(vbTab & "<tr>" & vbCrLf) ' Ny tabellrad

Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(0)) ' Kolumen noll, förnamn
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn

Response.Write(vbTab & vbTab & "<td>") ' Ny tabellkolumn
Response.Write(field(1)) ' Kolumn 1 , efternamn
Response.Write("</td>" & vbCrLf) ' Avsluta tabellkolumn





Response.Write(vbTab & "</tr>" & vbCrLf) ' Avsluta tabellrad
Loop
Response.Write("</table>") ' Avsluta tabell
Set TS = nothing
Else
Response.Write("Error: Filen finns inte!")
End If
Set FSO = nothing
%>

</code>

Då får jag: Felaktigt matrisindex: '[number: 1]'
Fan...står helt still i skallen. Märks att det var ett tag sedan jag skrev ASP. Man glömmer fort :P

Mvh Andreas