Jag har ett formulär som när man trycker på sänd uppdaterar en databas. Men jag vill lägga till en information att man skall kuna hämta ett nytt nummer i en nummerserie till mitt formulär. Problemet är att jag vill ha kvar de data man redan fyllt i formuläret efter man hämtat talet. Du måste nog skicka datat i vilket fall som helst eller om det kanske kan lösas med Javascript på clientsidan.Skicka data med ASP
Vad jag vet kan man bara innesluta textrutorna i en form tag. Och skall man använda sej av Request.QueryString så måste man ju först skicka data via post.
Några tips?Sv: Skicka data med ASP
Själv använder jag mig av följande:
<%
Option Explicit
Response.Buffer = TRUE
Dim strName, strEmail, strAction
%>
<html>
<head>
<title>Posta och fånga upp</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>
<body bgcolor="#FFFFFF" text="#000000">
<%
Call Main
'----------------------------------------------------------------------------------
'## -- main rutin --
Sub Main
Dim strScriptName
'## -- vilken sida är vi på just nu --
strScriptName = Request.ServerVariables("SCRIPT_NAME")
'## -- hämta data skickad till denna sida --
Call CollectFormData
Select Case UCase(strAction)
Case "GETNUMBER"
'## -- här lägger du koden som ska köras när formuläret postas för att hämta tex ett nummer --
'## -- visa formuläret igen --
Call WriteForm(strScriptName & "?action=post")
Case "POST"
'## -- här läggs koden som ska köras när formuläret ska postas till db --
Case Else
Call WriteForm(strScriptName & "?action=getnumber")
End Select
End Sub
'## -- visa ett formulär för användaren --
Sub WriteForm(ByVal FormAction)
%>
<form name="form1" method="post" action="<% =FormAction%>">
Namn:
<input type="text" name="txt_Name" value="<% =strName%>">
<br>
Email:
<input type="text" name="txt_Email" value="<% =strEmail%>">
<input type="submit" name="Submit" value="Submit">
</form>
<%
End Sub
'## -- hämta data --
Sub CollectFormData
strAction = Request.QueryString("action")
strName = Trim(Request.Form("txt_Name"))
strEmail = Trim(Request.Form("txt_Email"))
End Sub
%>
</body>
</html>
Hoppas att du förstår logiken i koden, annars bara att ropa till
cya,
PatrikB