Hej!
Jag gör en sajt med en bilddatabas, där det dels finns ett publikt galleri, dels kan man logga in och skapa ett privat galleri. Jag har hittat script där besökare kan lägga in nya bilder från sin egen hårddisk till databasen/galleriet. Men om man nu besöker det publika galleriet och hittar en bild som man vill spara ner till sin egen hårddisk - hur gör man då?
När jag ska lägga in en ny bild kan jag använda mig av en" input file field" för att kunna navigera bland mappar och filer på min dator med en browserknapp. Där kan man ju välja en bild t ex och klicka "open". Men hur gör man för att istället för "open" få en "save"-funktion - alltså plocka hem en bild och lägga den i valfri mapp på sin dator?

Säg nu inte att jag ska be besökarna att högerklicka och välja "save as"...det är det svaret jag fått hittills...

/Cicci

tror du hittar nåt i forumet om filestreaming.. det är ett enkelt sätt.. prova det..

Du har fått svar på denna frågan förut...

http://www.pellesoft.nu/development/forum/view.asp?msgid=41333&forumid=1&sum=1

/Johan

oooops.....

TACK JOHAN!!!

Testade det med att streama filer till webbläsaren. Filen jag la in i koden öppnades i browsern...
Men hur gör jag för att få upp en spararuta?
I HTML kan jag lägga in ett "file-field" med en browser-knapp, så jag får upp ett fönster med datorns mappar och filer - men där får jag bara upp "öppna"-funktionen. Vet du eller någon annan om jag kan få upp det fönstret med en "spara"-knapp istället??

/Cicci

Jag testade med denna koden nu och det fuingerade... Om detta inte fungerar vet jag inte vad som är fel...

<code>
<%
Response.ContentType = "application/octet-stream"
Response.AddHeader "Content-Disposition", "attachment;filename=produkt.jpg"

Const adTypeBinary = 1
Dim strFilePath

strFilePath = Server.MapPath("bild.jpg")

Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath

Response.BinaryWrite objStream.Read

objStream.Close
Set objStream = Nothing
%>
</code>

/Johan

Tack för hjälpen!

Jag fick det att funka med din kod! Så här gjorde jag:

<%@ Language=VBScript %>
<%
Dim rs
Dim conn
Dim SQL
Dim bild
Dim name

bild = Request.QueryString("bild")

SQL = "SELECT fltName FROM tblPubbilder WHERE fltbildID =" & bild

Set conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.Recordset")

conn.Open "DSN=dbpictureIT;UID=;PWD="
rs.Open SQL,conn,1,2

name = rs("fltName")

Response.ContentType = "application/octet-stream"
Response.AddHeader "Content-Disposition", "attachment;filename=" & name

Const adTypeBinary = 1
Dim strFilePath

strFilePath = Server.MapPath("/pictureIT/images/" & name)

Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath

Response.BinaryWrite objStream.Read

objStream.Close
Set objStream = Nothing

rs.Close
Set rs = Nothing
conn.Close
Set conn = Nothing
%>