En medlemsansökan till den fantastiska föreningen Krokoms Motocrossklubb!
Så här är det. Väljer man medlemsskapet Familj så får man skriva i hur många familjemedlemmar man har. Detta värde generar på nästa sida rätt antal former:

<code>
<%For iSlinga = 1 To antalmedlem%>
<form name="form1" method="post"action="medlem_mera_execute.asp">
<b>Namn</b> medlem <%=iSlinga%> <br>
<input name="namn1" size="20" >
<input type="text" name="personummer1" value="Personnummer h&auml;r">
<select name="traningavgift1">
<option selected>tr&auml;ningsavgift</option>
<option>Ingen</option>
<option>Knattar</option>
<option>80 cc</option>
<option>125-500 cc</option>
</select>
<%Next%>
</code>

Min stilla undran är hur jag bär mig åt för att skriva ner detta till databasen?
Databasen är Access..

Jag skulle satsa på att först skapa en array som tar in alla medlemmarna från din For loop. Sedan skulle jag loopa ut Arrayens innehåll med hjälp av For each Item in "Arrayen" loopen.

Dim Item, Array

For Each Item in Array
objCon.Execute "INSERT..."
Next

Ungefär så utan att nu ha tänkt igenom detta allför noga.
Spinn vidare på det!

Vet inte om det var så här du tänkte dig. Men kanske ger dig några tips och ideér:
<code>
<form name="form" method="post" action="medlem_mera_execute.asp">
<input type="hidden" name="antal" value="<%=antalmedlem%>">
<%
For iSlinga = 1 To antalmedlem
%>
Namn medlem <%=iSlinga%> <br>
<input name="namn<%=iSlinga%>" size="20" >
<input type="text" name="personummer<%=iSlinga%>" value="Personnummer här">
<select name="traningavgift<%=iSlinga%>">
<option value="" selected >träningsavgift</option>
<option>Ingen</option>
<option>Knattar</option>
<option>80 cc</option>
<option>125-500 cc</option>
</select>
<%
Next
%>
</form>



</code>
medlem_mera_execute.asp

<code>
<%
Function SQLText(Value)
If Len(Value) > 0 Then
SQLText = "'" & Replace(Value, "'", "''") & "'"
Else
SQLText = "Null"
End If
End Function

Dim con
Dim strSQL

Dim iSlinga
Dim antalmedlem

Dim Invalid

Dim Avgifter
Dim vTemp

antalmedlem = Request.Form("antal")

For iSlinga = 1 To antalmedlem
If Len(Request.Form("personummer" & iSlinga)) = 0 Then
Response.Write "Du har inte angivit personummer för " & iSlinga & "<br>" & vbCrLf
Invalid = True
End If
If Len(Request.Form("traningavgift" & iSlinga)) = 0 Then
Response.Write "Du har inte angivit traningavgift för " & iSlinga & "<br>" & vbCrLf
Invalid = True
End If
Next

If Invalid Then
Avgifter = Array("Ingen", "Knattar", "80 cc", "125-500 cc")
%>
<form name="form" method="post" action="medlem_mera_execute.asp">
<input type="hidden" name="Antal" value="<%=antalmedlem%>">
<%
For iSlinga = 1 To antalmedlem
%>
Namn medlem <%=iSlinga%> <br>
<input name="namn<%=iSlinga%>" size="20" >
<input type="text" name="personummer<%=iSlinga%>" value="<%=Request.Form("personummer" & iSlinga)%>">
<select name="traningavgift<%=iSlinga%>">
<option value="" >träningsavgift</option>
<%
For each vTemp In Avgifter
If vTemp = Request.Form("traningavgift" & iSlinga) Then
Response.Write " <option selected>" & vTemp & "</option>"
Else
Response.Write " <option>" & vTemp & "</option>"
End If
Next
%>
</select>
<%
Next
%>
</form>
<%
Else
Set con = Server.CreateObject("ADODB.Connection")
con.Open "<<<Din anslutninssträng>>>"

For iSlinga = 1 To antalmedlem
strSQL = "INSERT INTO TabellNamn (personummer, traningavgift) VALUES (" & SQLText(Request.Form("personummer" & iSlinga)) & ", " & SQLText(Request.Form("traningavgift" & iSlinga)) & ")"
con.Execute strSQL
Next
End if
%>
</code>