Tjena!
Har stött på en nytt problem… Vet inte riktigt hur jag skall köra SQL satserna.
Såhär ser det ut.

På Sida1.asp så listas alla som uppfyller sql satsen och en checkbox skriv ut på samma rad som varje post.
...
SQL = "SELECT * FROM Spelare Where Aktiv='Ja' ORDER BY Efternamn"
…
<input type="checkbox" name="checkbox-<%=RecSet("IDSpelare")%>" value="1">
…

Mitt problem är hur jag skall ta emot värdet från checkboxen på nästa sida och sätta in det i tabellen.

Har försökt att sätta in SQL satsen i en loop.
...
SQL = "SELECT * FROM Spelare Where Aktiv='Ja'"
Set RecSet = Connect.execute(SQL)

Do While Not RecSet.EOF

ID= RecSet("IDSpelare")
Utskick=Request.Form("checkbox-"&RecSet("IDSpelare")&"")

SQL = "UPDATE Spelare Set Utskick='"&Utskick&"' WHERE IDSpelare=" &ID
Set RecSet = Connect.execute(SQL)
loop
RecSet.MoveNext
...

Men det funkade ju såklart inte, om jag kör Response.Write på SQL så skivs den ju ut som jag vill att den skall köras.
Men det kanske inte funkar att ha två sql igång samtidigt ?

Mvh Marcus

sida1.php är inte en asp-fil!

Skrev fel... ursäkta!!!
Läste om php innan och det fastnade visst!

Mvh Marcus

döp om det sista recordsetet till recordset2

Testade det också igår men det ville sig inte. Men får göra ett nytt försök idag då!

Mvh Marcus

Vore det inte enklare att skriva:
<code>
Sida1.asp
…
<%
SQL = "SELECT * FROM Spelare Where Aktiv='Ja' ORDER BY Efternamn"
Set RecSet = Connect.execute(SQL)

Do Until RecSet.EOF
%>
…
<input type="checkbox" name="Spelare" value="<%=RecSet("IDSpelare") %>">
…
<%
RecSet.MoveNext
Loop
%>
…
</code>
mottagarsida:
<code>
...
<%
If Len(Request.Form("Spelare")) Then
SQL = "UPDATE Spelare SET Utskick= '1' WHERE Aktiv='Ja' AND IDSpelare IN(" & Request.Form("Spelare") & ")"
Connect.execute(SQL)
Response.Write "Spelare har uppdaterarts!"
Else
Response.Write "Inga markerade!"
End If
...
</code>
Eller om du även skall loopa igenom markerade:
<code>
...
<%
If Len(Request.Form("Spelare")) Then
SQL = "SELECT * FROM Spelare WHERE Aktiv='Ja' AND IDSpelare IN(" & Request.Form("Spelare") & ")"
Set RecSet = Connect.execute(SQL)

Do Until RecSet.EOF
'kod som gör något med spelaren
RecSet.MoveNext
Loop
SQL = "UPDATE Spelare SET Utskick= '1' WHERE Aktiv='Ja' AND IDSpelare IN(" & Request.Form("Spelare") & ")"
Connect.execute(SQL)
...
</code>

Tack för lösningen Anders!
Använde den första varianten, är kanske inte med på exakt hur den funkar men... det kanske lossnar snart!

Hur skulle det se ut om jag istället skulle ha tre textfält på sida1.asp

Mvh Marcus

Sida1.asp
<code>
…
<%
Dim IDSpelare
SQL = "SELECT * FROM Spelare Where Aktiv='Ja' ORDER BY Efternamn"
Set RecSet = Connect.execute(SQL)

Do Until RecSet.EOF
IDSpelare = RecSet("IDSpelare")
%>
…
<input type="checkbox" name="Spelare" value="<%=IDSpelare%>">
<input type="text" name="NickName<%=IDSpelare%>">
<input type="text" name="FirstName<%=IDSpelare%>">
<input type="text" name="LastName<%=IDSpelare%>">
…
<%
RecSet.MoveNext
Loop
%>
…
</code>
.asp
<code>
Function SQLText(Value)
If Len(Value) > 0 Then
SQLText = "'" & Replace(Value, "'", "''") & "'"
Else
SQLText = "Null"
End If
End Function

Dim IDSpelare
If Request.Form("Spelare").Count > 0 Then
For Each IDSpelare In Request.Form("Spelare")
SQL = "UPDATE Spelare SET NickName=" & SQLText(Request.Form("NickName" & IDSpelare)) & ", FirstName=" & SQLText(Request.Form("FirstName" & IDSpelare)) & ", LastName=" & SQLText(Request.Form("LastName" & IDSpelare)) & ", Utskick= '1' WHERE IDSpelare = " & IDSpelare
Connect.execute SQL
Next
Else
Response.Write "Inga markerade!"
End If
</code>