Hej har ett problem med min räknare.

Jag har en sida uppbyggd av tabeller. Länkar är givetvis querystings och räknare ligger i en tabellcell.
Problemet är att räknare lägger till en besökare för varje gång jag klickar på en länk.
Hur gör jag för att den bara ska räkna när man kommer in på sidan, och inte varje gång man går till en undersida? Har försökt att ordna det i global.asa men inte lyckats.
För jag anar att dt är där man löser problemet.

Räknarkoden:

<%
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & server.mappath("statistik.mdb")

SQL = "Select Count (*) As Antal From statistik Where Datum Like '%" & date & "%' "
Set RS = Connect.Execute(SQL)
SQL2 = "Select Count (*) As Antal From statistik Where Datum Like '%" & date-1 & "%' "
Set RS2 = Connect.Execute(SQL2)
SQL3 = "Select Count (*) As Antal From statistik"
Set RS3 = Connect.Execute(SQL3)
%>

Besök idag: <B><%=RS("Antal")%><BR></B>
Besök igår: <B><%=RS2("Antal")%><BR></B>
Besök&nbsp: <B><%=RS3("Antal")%><BR></B>

<%
RS.Close
Set RS = Nothing
RS2.Close
Set RS2 = Nothing
RS3.Close
Set RS3 = Nothing

SQL4 = "INSERT INTO statistik "
SQL4 = SQL4 & "(IP, Datum) "
SQL4 = SQL4 & "VALUES('"& Request.Servervariables("REMOTE_ADDR") &"','"& date &"')"

Connect.Execute(SQL4)
Connect.Close
Set Connect = Nothing
%>

Tacksam för all hjälp jag kan få.

Lägg koden som skapar posten i Global.Asa i Session_OnStart():
<code>
<SCRIPT LANGUAGE=ScriptLanguage RUNAT=Server>
Sub Session_OnStart
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & server.mappath("statistik.mdb")

strSQL = "INSERT INTO statistik (IP, Datum) " & vbCrLf & _
"VALUES('"& Request.Servervariables("REMOTE_ADDR") &"',#"& date &"#)"

Connect.Execute strSQL

Connect.Close
Set Connect = Nothing
End Sub
</SCRIPT>
</code>


Har lite förslag på optimeringar. Antar att Datum är av typen datum.
<code>
<%
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & server.mappath("statistik.mdb")

strSQL = "SELECT Count (*) As Antal, - Sum(Datum > #" & date & "#) As AntalIdag, - Sum(Datum > #" & Date - 1 & "#) As AntalIgår FROM statistik"
Set RS = Server.CreateObject("ADODB.Recordset")
RS.Open strSQL, Connect
%>
Besök idag: <B><%=RS("AntalIdag")%><BR></B>
Besök igår: <B><%=RS("AntalIgår")%><BR></B>
Besök&nbsp: <B><%=RS("Antal")%><BR></B>

<%
RS.Close
Set RS = Nothing

Connect.Close
Set Connect = Nothing
%>
</code>

Tackar så mycket har suttit två dar med det här nu. Men nu funkar det. Tack igen!