nått sånt härnt vill jag göra


SQL = "select col1,col2,col3 from tabell"
rs.open SQL, Connect
do until rs.EOF

for each col in ?????
col = ????

response.write(col & " ")

Next
rs.MoveNext
Loop
rs.Close


det är så att jag hämtar olika kolumner och vill därför loopa fram dom istället för att skriva i dom bara.

selecten kan alltså se helt annorlunda ut t.ex.
select col7,col2,col5 from tabell


det som ska stå i selecten skriver jag i en textruta på sidan.

<code>
for each field in rs.fields
Response.Write rs(field)
next
</code>

Om jag inte minns fel... ;)

Inte riktigt. Skippa rs. ;o)

Litet exempel:

<code>
<table>
<%
Dim rs
Dim field
Dim Connect

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open ">>>Connection String<<<"

Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open "SELECT col1,col2,col3 FROM tabell", Connect

Response.write "<tr>"
For Each field In rs.Fields
Response.write "<td><b>" & field.Name & "</b></td>"
Next
Response.write "</tr>"

Do Until rs.Eof
Response.write "<tr>"
For Each field In rs.Fields
Response.write "<td>" & Server.HTMLEncode(field.Value) & "</td>"
Next
Response.write "</tr>"
rs.MoveNext
Loop

rs.Close
Set rs = Nothing

Connect.Close
Set Connect = Nothing
%>
</table>
</code>

Tack Andreas!

Fungerade utmärkt:)

Tack. Är själv lite imponerad om den funerade dirket.
Eftersom skrev den bara ur minne utan att ha möjlighetet att testa. ;o)