Har problem, får hela tiden fel på rad 26(markerad). Felmeddelandet lyder felaktig operation på avslutat objekt. Har försökt ändra om i koden men får hela tiden fel. Tacksam för hjälp.

<%
IF Request.QueryString("laggt") = "laggtillannons" THEN

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "DSN=d1fdfffgh7g06-databasen;Password=@01#$hefgbdfffdfdfddfnfhokajljdbpjfdee"



namn = Request.Form("namn")
epost = Request.Form("epost")
tfn = Request.Form("tfn")
sort = Request.Form("sort")
kategori = Request.Form("kategori")
rubrik = Request.Form("rubrik")
annons = Request.Form("annons")
stime = Time
sdate = Date

Set connObj = Server.CreateObject("ADODB.Connection")

strSQL = "INSERT INTO annonser('namn','epost','tfn','sort','kategori','rubrik','annons','stime','sdate') VALUES('" & namn & "','" & epost & "','" & tfn & "','" & sort & "','" & kategori& "','" & rubrik & "','" & annons & "','" & stime & "','" & sdate & "')"

connObj.Execute(strSQL), RecordsAffected, adExecuteNoRecords <------ Rad 26


connObj.Close


IF RecordsAffected > 0 Then
Response.Write("Annonsen inlagd!")
END IF


END IF%>

Du arbetar med två olika variabler Connect och connObj. Den du anropar är inte öppen.

Testa med:
<code>
<%
Function SQLText(Value)
If Len(Value) > 0 Then
SQLText = "'" & Replace(Value, "'", "''") & "'"
Else
SQLText = "Null"
End If
End Function

Function SQLDate(Value)
If IsDate(Value) Then
SQLDate = "#" & FormatDateTime(Value, vbGeneralDate) & "#"
Else
SQLDate = "Null"
End If
End Function

IF Request.QueryString("laggt") = "laggtillannons" THEN
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "DSN=d1fdfffgh7g06-databasen;Password=@01#$hefgbdfffdfdfddfnfhokajljdbpjfdee"

namn = Request.Form("namn")
epost = Request.Form("epost")
tfn = Request.Form("tfn")
sort = Request.Form("sort")
kategori = Request.Form("kategori")
rubrik = Request.Form("rubrik")
annons = Request.Form("annons")
stime = Time
sdate = Date

strSQL = "INSERT INTO annonser(namn, epost, tfn, sort, kategori, rubrik, annons, stime, sdate) VALUES(" & SQLText(namn) & ", " & SQLText(epost) & ", " & SQLText(tfn) & ", " & SQLText(sort) & ", " & SQLText(kategori) & ", " & SQLText(rubrik) & ", " & SQLText(annons) & ", " & SQLDate(stime) & ", " & SQLDate(sdate) & ")"

Connect.Execute strSQL, RecordsAffected, adExecuteNoRecords
Connect.Close

If RecordsAffected > 0 Then
Response.Write("Annonsen inlagd!")
End If
End If
%>
</code>

Om du kör SQL server använd då istället '-tecknet som datum avskiljare:
<code>
Function SQLDate(Value)
If IsDate(Value) Then
SQLDate = "'" & FormatDateTime(Value, vbGeneralDate) & "'"
Else
SQLDate = "Null"
End If
End Function
</code>

Du fösöker använda objconn när din koppling heter Connect...


EDIT: eller vänta nu... var jag för snabb nu tro?

//M.

Tjena!

Använd "set nocount on" först i din query / sp så ska det funka!
Då får du bort räknaren som ställer till det... =)

Mvh Erik