Hej
Jag försöker att skapa och skriva till ett Excel dokument från ASP. men hur gör man om man vill lägga till ytterligare ett arbetsblad? Dom första tre är ju inga problem efter som dessa öppnas som standard.
Min kod:

dim oExcel

set oExcel = server.createObject("Excel.Application")
Set fso = server.createobject("Scripting.FileSystemObject")

'--Delete gammal fil om det finns
filename = "C:\Temp\test.xls"
If fso.FileExists(filename) Then
fso.DeleteFile filename, True
End If

oExcel.Visible = True
oExcel.Application.Workbooks.Add
oExcel.Application.DisplayAlerts = False
oExcel.Application.DisplayAlerts = True

'-- Skriver namnen till arbetsbladen ---------------------------
oExcel.Application.Worksheets(1).Name = "New Hardware Allocation"
oExcel.Application.Worksheets(2).Name = "Department Application Profile"
oExcel.Application.Worksheets(3).Name = "Users Non Standard Hardware"

oExcel.ActiveWorkbook.SaveAs(filename)
oExcel.ActiveWorkbook.Close
oExcel.Quit
set oExcel = nothing

Nåt sånt här borde fungera

<code>
With oExcel.Application.Workbooks.Add
.Worksheets(1).Name = "New Hardware Allocation"
.Worksheets(2).Name = "Department Application Profile"
.Worksheets(3).Name = "Users Non Standard Hardware"
With .Sheets.Add
.Name = "Ditt namn"
End With

End With
</code>

JAg skulle skrivit såhär:
<code>
Dim oExcel
Dim oBook
Dim oSheet
Dim filename

filename = "C:\Temp\test.xls"

'--Delete gammal fil om det finns
Set fso = Server.CreateObject("Scripting.FileSystemObject")
If fso.FileExists(FileName) Then
fso.DeleteFile FileName, True
End If

Set oExcel = Server.CreateObject("Excel.Application")
'oExcel.Visible = True
oExcel.DisplayAlerts = False


Set oBook = oExcel.Workbooks.Add()

'-- Skriver namnen till arbetsbladen ---------------------------
'Det skall minst finnas 6
If oBook.Worksheets.Count < 6 Then
oBook.Worksheets.Add , oBook.Worksheets(oBook.Worksheets.Count), 6 - oBook.Worksheets.Count
End If

oBook.Worksheets(1).Name = "New Hardware Allocation"
oBook.Worksheets(2).Name = "Department Application Profile"
oBook.Worksheets(3).Name = "Users Non Standard Hardware"
oBook.Worksheets(4).Name = "Nummer 4"
oBook.Worksheets(5).Name = "Nummer 5"
oBook.Worksheets(6).Name = "Nummer 6"

'Lägga till enstaka
Set oSheet = oBook.Worksheets.Add(, oBook.Worksheets(oBook.Worksheets.Count))
oSheet.Name = "Wow, det fungerar igen!"
Set oSheet = Nothing

oBook.SaveAs FileName
oBook.Close False
Set oBook = Nothing

oExcel.Quit
Set oExcel = Nothing
</code>

Härligt detta funkade kanooon!!! Tackar tackar!! (Det senaste svaret alltså)
/Micke