Hej !

Jag har en mapp som heter bilder
och i bilder finns det tex 3 mappar.

/bilder/030714/
/bilder/030723/
/bilder/030730/

och varsin mapp innehåller ett visst antal bilder.

Det jag nu vill göra är att generera en tabell
med 2 kolumner och 1 rad.

I den tabellen så vill jag försöka få i första kolumnen
den första mappens namn utskriven (030714) och i den
andra kolumnen en slumpad bild i miniformat visad. tex
/bilder/030714/bild34.jpeg


tex

----------------------------------------------
030714 | /bilder/030714/bild344.jpeg |
(första mappens| (slumpad bild ur mappen) |
namn) | |
----------------------------------------------
----------------------------------------------
030714 | /bilder/030714/bild344.jpeg |
(första mappens| (slumpad bild ur mappen) |
namn) | |
----------------------------------------------


den ska generera lika många 2X1 tabeller som det finns
mappar

alltså i detta fall skriva ut 3 stycken 2X1 tabeller.


Väldigt tacksam för utförliga svar, gärna kod!

Svar uppskattas!!

Gew din inlägg en lämplig rubrik...


<code>
Dim FSO
Dim Bilder
Dim Folder
Dim File
Dim Index

Randomize

Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set Bilder = FSO.GetFolder("C:\")

For Each Folder In Bilder.SubFolders
Response.Write "<TABLE><TR><TD>" & Server.HTMLEncode(Folder.Name) & "</TD><TD>"
If Folder.Files.Count Then
Index = Rnd * Folder.Files.Count
For Each File In Folder.Files
If Index > 0 Then
Index = Index - 1
Else
Response.Write "<IMG scr=""/bilder/" & Folder.Name & "/" & File.Name & """>"
Exit For
End If
Next
Else
Response.Write "Empty"
End If
Response.Write "</TD></TABLE>"
Next
</code>

Nu fungerar det nästan..
jag får fram filnamnet men inte bilden
kollar jag källan på htmlen som är genererad så stämmer sökvägen men bilden vägrar komma upp..

deb blir en liten ruta (den verkar inte hitta bilden men den skriver inte emtpy.
kolla på http://www.jrmusik.net/jr2/live.asp

... vad kan det vara =
tacksam för svar

ÄR sökvägen korrekt? Vart ligger bilder mappen på din server.

själva indexfilen för sidan ligger på
www.jrmusik.net/jr2/index.asp

och aspfilen som jag gjort för att visa bilderna ligger under

/jr2/live.asp

bilderna ligger under

/jr2/pic/y/mapp1 mapp2 mapp3 etc

om jag lägger en bild under asp koden och jämför med den genererade
imgsrc: .....
så stämmer de överens men bilden vill inte visas ..
kolla på www.jrmusik.net/jr2/live.asp

He, he... JAg som är ond och elak.
Testa att ändra scr till src i IMG tagen. ;o)

hehe
tack nu visas bilderna, men... hm

hur gör jag för att den bara ska visa .jpg bilderna
och sätta storleken på dessa?

detta verkade itne fung när det gäller storleken?
Response.Write "<IMG src=""/JR2/Pic/y/" & Folder.Name & "/" & File.Name & """"width="107" height="67"" >"

<code>
Dim FSO
Dim Bilder
Dim Folder
Dim File
Dim Url
Dim Index
Dim Dictionary

Randomize

Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set Dictionary = Server.CreateObject("Scripting.Dictionary")
Set Bilder = FSO.GetFolder(Server.MapPath("/JR2/Pic/y/"))

For Each Folder In Bilder.SubFolders
Response.Write "<TABLE><TR><TD>" & Server.HTMLEncode(Folder.Name) & "</TD><TD>"
For Each File In Folder.Files
If LCase(Right(File.Name, 4)) = ".jpg" Then
Dictionary.Add Dictionary.Count, File.Name
End If
Next

If Dictionary.Count Then
Index = Int(Rnd * Dictionary.Count)
Url = "/JR2/Pic/y/" & Folder.Name & "/" & Dictionary.Item(Index)
Response.Write "<A target=""_blank"" href=""" & Url & """><IMG src=""" & Url & """ Width=""107"" Height=""67""></A>"
Dictionary.RemoveAll
Else
Response.Write "Empty"
End If
Response.Write "</TD></TABLE>"
Next
</code>

Hej,

Om man har Å, Ä, Ö i filnamnet funkar inte detta... kan man lösa det på något sätt eller måste man döpa allt utan ÅÄÖ ?

/Henrik

Du kan testa med:
<code>
Response.Write "<A target=""_blank"" href=""" & Server.URLEncode(Url) & """><IMG src=""" & Url & """ Width=""107"" Height=""67""></A>"
</code>

Nä, det blir ingen lösning... några fler förslag?
mvh
/Henrik