Hej.

Jag undrar hur man tar reda på om ett nummer i en variabel är jämt eller ojämt.
Det är nämligen en variabel som ligger i en loop och för varje gång loopen körs så läggs det till 1 till variabeln och sedan ska det ske olika saker beroende på om variabeln är ett jämt eller ojämt nummer.

Tack
Katarina

Hej

Använd dig av MOD

text om dinVariabel MOD 2 = 1 OJÄMT
dinVariabeln MOD 2 = 0 JÄMT

Borde funka

Hej.

Tack så mycket, det fungerade!

Katarina

Litet exempel:
<%
Dim Index
Dim Even
Dim Odd
For Index = 1 To 100
If Index And 1 Then
Odd = Odd + 1
Else
Even = Even + 1
End If
Next
%>
Odd: <%=Odd%><BR>
Even: <%=Even%><BR>

Om du använder dig av ett recordset kan ett alternativ till att öka med ett var att invertera värdet:

<%
Function TestRecordset()
Dim rsTemp
Set rsTemp= server.CreateObject("ADODB.Recordset")
rsTemp.Fields.Append "Field1", 200, 25
rsTemp.Fields.Append "Field2", 200, 25
rsTemp.Fields.Append "Field3", 200, 25
rsTemp.Open

rsTemp.AddNew array("Field1","Field2","Field3"),array("Item 1.1","Item 1.2","Item 1.3")
rsTemp.AddNew array("Field1","Field2","Field3"),array("Item 2.1","Item 2.2","Item 2.3")
rsTemp.AddNew array("Field1","Field2","Field3"),array("Item 3.1","Item 3.2","Item 3.3")
rsTemp.AddNew array("Field1","Field2","Field3"),array("Item 4.1","Item 4.2","Item 4.3")
rsTemp.AddNew array("Field1","Field2","Field3"),array("Item 5.1","Item 5.2","Item 5.3")

rsTemp.MoveFirst
Set TestRecordset = rsTemp
End function
%>

<TABLE WIDTH="100%" BORDER=1 CELLSPACING=1 CELLPADDING=1>
<%
Dim rsTemp
Dim Odd
Set rsTemp = TestRecordset

Do Until rsTemp.EOF
If Odd Then
%>
<TR bgColor=yellow>
<TD><%=rsTemp("Field1")%></TD>
<TD><%=rsTemp("Field2")%></TD>
<TD><%=rsTemp("Field3")%></TD>
</TR>
<%
Else
%>
<TR>
<TD><%=rsTemp("Field1")%></TD>
<TD><%=rsTemp("Field2")%></TD>
<TD><%=rsTemp("Field3")%></TD>
</TR>
<%
End If
Odd = Not Odd
rsTemp.MoveNext
Loop
%>
</TABLE>