Detta ex läser ju bara en rad
Om jag vill kunna läsa flera rader från en fil
Hur gör jag då?

Open "TT.txt" For Input As #1
Line Input #1, Text
Text2.Text = Text2.Text + Text
Close



Sören

KAnske så här du menar:
<code>
Dim FileNo as long
Dim strLine as string
FileNo = FreeFile()
Open "TT.txt" For Input As #FileNo
Do Until EOF(FileNo)
Line Input #FileNo, strLine
Text2.Text = Text2.Text + strLine
Loop
Close FileNo
</code>

Ja nästan
Detta ger ju en lång rad
Men om man vill ha dom radvis, precis som när man läser dom

Då behöver du inte läsa radvis. Läs in hela filen istället.
<code>
Dim FileNo As Long
Dim FileName As String
Dim strText as string
FileNo = FreeFile()
FileName = "TT.txt"

Open FileName For Binary Access Read As #FileNo
strText = Space(LOF(FileNo))
Get #FileNo, , strText
Close FileNo

Text2.Text = strText
</code>

kan man inte göra så här också??

Dim FileNo as long
Dim strLine as string
FileNo = FreeFile()
Open "TT.txt" For Input As #FileNo
Do Until EOF(FileNo)
Line Input #FileNo, strLine
Text2.Text = Text2.Text + strLine & vbCrlf
Loop
Close FileNo

undrar BJ utan att testa

Det kan man göra. Men det är mycket ineffektivt.
* Att läsa från hårdisken är en långsam operation.
* Line input innebär en sökning till nästa radbrytning.
* Sträng konkratenering kräver att du dimensionerar om variabeln för varje tilldelning. Vilket stjäl tid.
* Att anrop egenskapen på textbox långsamare än att använda en variabel.

Däremot strular binary om filen är i unicodeformat.

Tackar för detta.

Hej
Mitt favoritsätt har blivit

Dim FileNo As Long
Dim tmpStr As String
FileNo = FreeFile
Open "TT.txt" For Input As #FileNo
'Läs hela texten i en chunk
tmpStr = Input$(LOF(FileNo),FileNo)
Close FileNo
Text1.Text = tmpStr 'Text1 MultiLine = True

Sven

Har du något förslag för unicode filer?

hej
Menar du att inte mitt exempel funkar på Unicode ?

DS