finns det något sätt som jag kan hämta iconen från ett fönster som jag känner till vis hWnd?

/Patrik

Du skickar WM_GETICON medelandet till fönstret, så får du handtaget till iconen.

hmmm, jag får inte det att fungera. Jag har följande programkod:
hIcon = SendMessage(app_hwnd, WM_GETICON, byval 0&, byval 0&)
och jag får bara 0 i hIcon

/Patrik

Testa med:
<code>
Option Explicit

Private Declare Function SendMessageTimeout _
Lib "user32" _
Alias "SendMessageTimeoutA" _
(ByVal hWnd As Long, _
ByVal msg As Long, _
ByVal wParam As Long, _
ByVal lParam As Long, _
ByVal fuFlags As Long, _
ByVal uTimeout As Long, _
lpdwResult As Long) As Long

Private Declare Function GetClassLong _
Lib "user32" _
Alias "GetClassLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long) As Long

Private Const GCL_HICON As Long = (-14&)
Private Const GCL_HICONSM As Long = (-34&)
Private Const WM_GETICON As Long = &H7F&
Private Const WM_SETICON As Long = &H80&
Private Const ICON_SMALL As Long = 0&
Private Const ICON_BIG As Long = 1&


Public Function GetWndIcon(hWnd As Long) As Long
SendMessageTimeout hWnd, _
WM_GETICON, _
ICON_SMALL, _
0&, _
0&, _
1000&, _
GetWndIcon

If GetWndIcon = 0 Then
GetWndIcon = GetClassLong(hWnd, GCL_HICONSM)
End If
End Function
</code>

Tack det fungerade

/Patrik