Hur får jag flera nivåer av funktioner och egenskaper i en ActiveX – Control
Så här har jag det nu för de olika funktionerna och egenskaper

Progressbar1.ProgPicture_hdc ‘används till Api-t BitBlt
Progressbar1.ProgColor = 013241654 ‘Byter färg
Progressbar1.ProgPicture = LoadPicture(“Archive.bmp") ‘ Laddar bmpbild

Så här skulle jag villa ha det.

Progressbar1.Picture.hdc ’ används till Api-t BitBlt
Progressbar1.Picture.Color = 013241654
Progressbar1.Picture.Picture = LoadPicture(“Archive.bmp") ‘ Laddar bmpbilder


Flera nivåer finns I tex. Listviewkontrollen

Någon som har en ide

Du retunerar att objekt för egenskapen Picture som stödjer de medlemmarna du vill använda.

Exempel:

'Class module: clsPicture
' Instancing = 2 - PublicNotCreatable
Option Explicit

Private mhDC As Long
Private mColor As OLE_COLOR
Private mPicture As New StdPicture

Public Property Get hDC() As Long
hDC = mhDC
End Property
Public Property Let hDC(vData As Long)
mhDC = vData
End Property

Public Property Get Color() As OLE_COLOR
Color = mColor
End Property
Public Property Let Color(vData As OLE_COLOR)
mColor = vData
End Property

Public Property Get Picture() As StdPicture
Set Picture = mPicture
End Property
Public Property Set Picture(vData As StdPicture)
Set mPicture = vData
End Property

'User Control: Progressbar

Option Explicit

Private mPicture As clsPicture

Public Property Get Picture() As clsPicture
Set Picture = mPicture
End Property

Private Sub UserControl_Initialize()
Set mPicture = New clsPicture
End Sub

Private Sub UserControl_Terminate()
Set mPicture = Nothing
End Sub

Hur får jag tillgång till min picturebox som ligger i usercontrol från Class modulen det måste ju hända någonting också.

Tja, var bara tänkt som en knuff i rätt riktning...
Men här kommer en litemer avancerad lösning:

'Class module: clsPicture
' Instancing = 2 - PublicNotCreatable
Option Explicit

Public Color As OLE_COLOR
Public Picture As StdPicture

Public Property Get hDC() As Long

End Property


'User Control: Progressbar
Option Explicit

Implements clsPicture

Public Property Get Picture() As clsPicture
Set Picture = Me
End Property

Private Property Get clsPicture_Color() As stdole.OLE_COLOR
clsPicture_Color = Picture1.BackColor
End Property
Private Property Let clsPicture_Color(ByVal RHS As stdole.OLE_COLOR)
Picture1.BackColor = RHS
End Property

Private Property Get clsPicture_hDC() As Long
clsPicture_hDC = Picture1.hDC
End Property

Private Property Set clsPicture_Picture(ByVal RHS As stdole.Picture)
Set Picture1.Picture = RHS
End Property
Private Property Get clsPicture_Picture() As stdole.Picture
Set clsPicture_Picture = Picture1.Picture
End Property