Hej
Nån som kan berätta hur jag laddar in bilder från en specifik mapp
så bildnamnen kommer upp i en lista så att jag sen därifrån kan
kolla dom
vill att det ska ske i form load händelsen och alla bildnamnen ska
synas i list1 t.ex

Detta har, naturligtvis, ingenting med riskhantering att göra. Total felpost alltså.

Som svar på din fråga: ett sätt är att använda funktionen Dir på en mapp, anropas med filnamn först och sen utan.

I VB 6, jag antar att du programmerar i VB då du nämner Form_load, finns det en kontroll som heter FilListBox. Ikonen i toolbaren påminer om ikonen för ett text dokument. Dena kontroll listar filer i en angiven katalog.

Om du lägger in En DriveListBox, en DirListBox, en FileListBox och en Image kontroll på ett formulär och klistrar in följande kod:

Option Explicit

Private Sub Dir1_Change()
On Error GoTo Dir1_Change_Err
    File1.Path = Dir1.Path

Dir1_Change_Exit:
    Exit Sub
    
Dir1_Change_Err:
    MsgBox Err.Description
    Resume Dir1_Change_Exit
End Sub

Private Sub Drive1_Change()
On Error GoTo Drive1_Change_Err
    Dir1.Path = CurDir(Drive1.Drive)

Drive1_Change_Exit:
    Exit Sub
    
Drive1_Change_Err:
    MsgBox Err.Description
    Resume Drive1_Change_Exit
End Sub

Private Sub File1_Click()
On Error GoTo File1_Click_Err
    If File1.ListIndex = -1 Then
        Set Image1.Picture = Nothing
    Else
        Set Image1.Picture = LoadPicture(File1.Path & "\" & File1.FileName)
    End If
    
File1_Click_Exit:
    Exit Sub
    
File1_Click_Err:
    MsgBox Err.Description
    Resume File1_Click_Exit
    
End Sub

Private Sub Form_Load()
    File1.Pattern = "*.bmp;" + _
                    "*.dib;" + _
                    "*.gif;" + _
                    "*.jpg;" + _
                    "*.wmf;" + _
                    "*.emf;" + _
                    "*.ico;" + _
                    "*.cur"
    Drive1.Drive = Environ("SystemDrive")
    Dir1.Path = Environ("SystemRoot")
End Sub