...jag listar bildfiler i en mapp på min sida...
...de visas som bilder...
...de visas med den äldsta först, men jag skulle vilja ha det omvänt...
...alltså den senaste först...
...finns det ngn som har koll på om det är mögligt & i så fall hur???

Tror inte du kan sortera i FSO!

Annars så finns det mycket info om FSO på msdn.microsoft.com/scripting

Tyvärr.

En lösningen är att läsa in datumet som filerna ändrades senast och lägga allt i en array och sedan sortera den arrayen som du vill.

En enkel lösning om du vill ändra på sorteringen är att istället för att skriva ut bilderna direkt är att loopa dessa in i en variabel och sen skriva ut dessa.

Enkel beskrivning

For i = 1 To 10
strTemp = i & "<br>" & strTemp
Next
Response.Write strTemp

Nu har du ändrat sorteringen på 1 till 10 till 10 till 1.

Det finns flera knep med det är väl det enklaste.

/Janne

Om du vill göra det enkelt använder du ett recordset:

<code>
<%
Dim Fields
Dim strPath

Dim rsTemp
Dim FSO
Dim File
Dim Folder

Const adDate = 7
Const adDecimal = 14
Const adVarChar = 200
strPath = server.MapPath(".")

Set rsTemp = CreateObject("ADODB.Recordset")
rsTemp.Fields.Append "Path", adVarChar, 255
rsTemp.Fields.Append "Name", adVarChar, 255
rsTemp.Fields.Append "Size", adDecimal
rsTemp.Fields.Append "Created", adDate
rsTemp.Fields.Append "LastModified", adDate
rsTemp.Fields.Append "LastAccessed", adDate

rsTemp.Open

Select Case LCase(Request.Querystring("sort"))
Case "path"
rsTemp.Sort = "Path"
Case "size"
rsTemp.Sort = "Size"
Case "created"
rsTemp.Sort = "Created"
Case "lastmodified"
rsTemp.Sort = "LastModified"
Case "lastaccessed"
rsTemp.Sort = "LastAccessed"
Case Else 'Name
rsTemp.Sort = "Name"
End Select

Fields = Array("Path", "Name", "Size", "Created", "LastModified", "LastAccessed")

Set FSO = CreateObject("Scripting.FileSystemObject")
Set Folder = FSO.GetFolder(strPath)
For Each File In Folder.Files
rsTemp.AddNew Fields, Array(strPath, File.Name, File.Size, File.DateCreated, File.DateLastModified, File.DateLastAccessed)
Next

rsTemp.MoveFirst

'Alternativ till loop
Response.Write "<Table>"
Response.Write "<TR><TD>Path</TD>"
Response.Write "<TD>Name</TD>"
Response.Write "<TD>Size</TD>"
Response.Write "<TD>Created</TD>"
Response.Write "<TD>Last Modified</TD>"
Response.Write "<TD>Last Accessed</TD></TR>" & vbCrLf
Response.Write "<TR><TD>"
Response.Write rsTemp.GetString(, , "</TD><TD>", "</TD></TR>" & vbCrLf & "<TR><TD>")
Response.Write "</TD></TR>"

rsTemp.Close
%>
</code>

...tack för svaren!!!
...får se hur jag gör - när jag sätter mig ner & brottas med problemet nästa gång bestämmer jag mig för vilken metod jag anser fungerar...
...jag tittar alltså inte på det nu, men tack för svaren i alla fall...